Bonjour,
Je reprends ici l'un des polyèdres cités en exemple au cours des échanges sur les oloïdes (message #09)
http://www.bibmath.net/forums/viewtopic.php?id=13733
L'objet est construit sur deux groupes de 3 segments de même longueur, respectivement situés dans les plans (xOz) et (yOz) du repère orthonormé direct orientant l'espace, et dont l'axe de symétrie commun (z'z) constitue l'axes de roto-inversion d'ordre (4) de l'ensemble.
Il n'y a pas de symétrie centrale.
La programmation des positions des 8 sommets envisagés ne présente aucune difficulté:
PROGRAM Polyedre;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Repr‚sentation en perpective des faces d'un poly‚dre … 26 faces
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
USES Crt, E_Texte, U_Copie_1F, Math, U_Math;
CONST Nsomm = 8; Nface = 12;
TYPE Ve3D = RECORD x, y, z: Reel END;
Tab_V = ARRAY[1..Nsomm] OF Ve3D;
Face = RECORD Sa, Sb, Sc: Byte;
Un: Ve3D; Dc: Reel END;
Tab_F = ARRAY[1..Nface] OF Face;
Tab_C = ARRAY[1..Nface] OF Pixel;
VAR Rcen: Z_32;
Vun1, Vun2, Vun3: Ve3D;
LstS: Tab_V;
LstF: Tab_F;
LstC: Tab_C;
// ... / ...
CONST DegRad = Pi / 180; AlphaDeg = 32.0; // Valeur de Alpha en degr‚s
PROCEDURE AffSxyz;
CONST L1 = 2; L2 = L1 + 1; v = 12; w = 5;
VAR k: Byte;
BEGIN
E(1012); Wt(1, L1, ' k');
E(0015); Write(' x y');
E(0011); Write(' z');
FOR k:= 1 TO Nsomm DO
BEGIN
E(0012); We(1, k + L2, k, w);
E(0015); Write(LstS[k].x:v:w, LstS[k].y:v:w);
E(0011); Write(LstS[k].z:v:w)
END;
E(0015); Wt(49, L1, 'Valeur de Alpha:');
E(0011); Wr(49, L1 + 2, AlphaDeg, 1003); Write(' ø')
END;
PROCEDURE Calc_S(Rsph: Reel; VAR L_s: Tab_V);
VAR k:Byte; Alpha1, C1, C3, Rc1, Rc3, Rs1, Rs3, S1, S3: Reel;
BEGIN
Alpha1:= AlphaDeg * DegRad;
SinCos(Alpha1, S1, C1); SinCos(3 * Alpha1, S3, C3);
Rc1:= Rsph * C1; Rs1:= Rsph * S1;
Rc3:= Rsph * C3; Rs3:= Rsph * S3;
L_s[1].x:= Rs3; L_s[2].x:= Rs1; L_s[3].x:= -Rs1; L_s[4].x:= -Rs3;
L_s[1].z:= Rc3; L_s[2].z:= Rc1; L_s[3].z:= Rc1; L_s[4].z:= Rc3;
FOR k:= 1 TO 4 DO L_s[k].y:= 0;
L_s[5].y:= Rs3; L_s[6].y:= Rs1; L_s[7].y:= -Rs1; L_s[8].y:= -Rs3;
L_s[5].z:= -Rc3; L_s[6].z:= -Rc1; L_s[7].z:= -Rc1; L_s[8].z:= -Rc3;
FOR k:= 5 TO 8 DO L_s[k].x:= 0; AffSxyz
END;
Il faut ensuite inventorier les diverses faces, lesquelles se caractérisent par:
# les indices respectifs (Ja, Jb, Jc) de leurs 3 sommets, donnés dans l'ordre croissant,
# les composantes du vecteur unitaire normal (Un), et
# la distance (Dc) les séparant de l'origine (O) du repère, et dans le cas présent centre de la sphère circonscrite au polyèdre.
Le critère de reconnaissance d'une face consiste en ceci que pour un triplet (i, j, k) donné, tous les autres points sont situés, comme l'origine, du même côté par rapport au plan (M
i, M
j, M
k);
par conséquent les produits mixtes (
MiMj,
MiMk,
MiMl) et (
MiMj,
MiMk,
MiO) sont de même signe pour tout (l) différent de (i, j) et (k).
Il n'y a ici que des faces triangulaires; la présence de faces à plus de 3 sommets n'introduit pas de difficulté insurmontable.
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
D‚termination des sommets, des faces et des arˆtes
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
PROCEDURE AffF(VAR L_F: Tab_F);
CONST L1 = 14; L2 = L1 + 1; v = 11; w = 5;
VAR k: Byte;
BEGIN
E(0012); Wt(1, L1, ' j');
E(0015); Write(' Ja Jb Jc ');
E(0010); Write('Nx Ny Nz ');
E(0014); Write('Dcen');
FOR k:= 1 TO Nface DO
WITH L_f[k] DO
BEGIN
E(0012); We(1, k + L2, k, w);
E(0015); Write(Sa:w, Sb:w, Sc:w);
E(0010); Write(Un.x:v:w, Un.y:v:w, Un.z:v:w);
E(0014); Write(Dc:v:w)
END;
A_
END;
PROCEDURE Calc_F(VAR L_F: Tab_F);
CONST Vzero: Ve3D = (x:0; y:0; z:0); Epsilon = -1E-10;
VAR h, i, j, k, l: Byte; Pcen, q: Reel;
Wj, Wk, Wn, Wcen, Wl: Ve3D; Test: Bool;
BEGIN
h:= 0;
FOR i:= 1 TO (Nsomm - 2) DO
BEGIN
Wcen:= Diff2V(Vzero, LstS[i]);
FOR j:= (i + 1) TO (Nsomm - 1) DO
FOR k:= (j + 1) TO Nsomm DO
BEGIN
Wj:= Diff2V(LstS[j], LstS[i]);
Wk:= Diff2V(LstS[k], LstS[i]);
Wn:= Pvect(Wj, Wk); Pcen:= Pscal(Wn, Wcen);
IF (Abs(Pcen)>Epsilon) THEN
BEGIN
Test:= True;
FOR l:= 1 TO Nsomm DO
IF (l<>i) AND ((l<>j) AND (l<>k)) THEN
BEGIN
Wl:= Diff2V(LstS[l], LstS[i]);
q:= Pscal(Wn, Wl);
IF ((Pcen * q)<-Epsilon) THEN Test:= False
END;
IF (Test AND (h<Nface)) THEN
BEGIN
Inc(h);
WITH L_F[h] DO
BEGIN
Sa:= i; Sb:= j; Sc:= k;
Un:= Vunit(Pcen, Wn); Dc:= Pscal(LstS[i], Un)
END
END
END
END
END
END;
L'identification des arêtes est ici inutile.
L'affichage des données relatives aux sommets et aux faces permet de s'assurer de la conformité géométrique de l'objet attendu:
Reste à donner le programme principal, les calculs préliminaires relatifs au nouveau repère et à la palette de couleur
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Calcul des couleurs
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
FUNCTION Lum(p: Reel): Byte;
VAR u, v, w: Reel;
BEGIN
// u:= 1 + p; v:= Sqr(p - 0.5); w:= Sqrt(u * v);
// Result:= Round(361.331 * w)
u:= Sqrt(1 + p); Result:= Round(180.6657 * u)
END;
PROCEDURE Init_Lc(VAR L_c: Tab_C);
VAR k: Byte; Px: Pixel;
BEGIN
FOR k:= 1 TO Nface DO
WITH LstF[k].Un DO BEGIN
Px[1]:= Lum(-x); Px[2]:= Lum(y);
Px[3]:= Lum(-z); L_c[k]:= Px
END
END;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Calculs relatifs au nouveau repŠre
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
PROCEDURE CalcRc(La, Ha: Z_32; VAR Rs_: Z_32);
BEGIN
IF (La<Ha) THEN Rs_:= La DIV 2
ELSE Rs_:= Ha DIV 2
END;
CONST LambdaDeg = 3.0; PhiDeg = 20.0;
PROCEDURE Calc_U0123(VAR U_1, U_2, U_3: Ve3D);
CONST DegRad = Pi / 180;
VAR Clam, Cphi, Slam, Sphi: Reel; W: Ve3D;
BEGIN
SinCos(LambdaDeg * DegRad, Slam, Clam);
SinCos(PhiDeg * DegRad, Sphi, Cphi);
W.x:= -Sphi; W.y:= Cphi; W.z:= 0; U_1:= W;
W.x:= - Slam * Cphi; W.y:= - Slam * Sphi; W.z:= Clam; U_2:= W;
W.x:= Clam * Cphi; W.y:= Clam * Sphi; W.z:= Slam; U_3:= W
END;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Programme principal
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
BEGIN
Copie_F1; A_;
Calc_U0123(Vun1, Vun2, Vun3); CalcRc(Larg_Image, Haut_Image, Rcen);
Calc_S(Rcen * 0.960, LstS); AffSxyz;
Calc_F(LstF); AffF(LstF);
Init_Lc(LstC);
Calc_Mat_Im2(Larg_Image, Haut_Image, Rcen, Matrice_2);
Creation_F2
END.
... et enfin le tracé de l'image, ainsi que les fonctions utilitaires:
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Utilitaires
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
FUNCTION Pvect(Wa, Wb: Ve3D): Ve3D;
VAR p, q: Reel; W: Ve3D;
BEGIN
p:= Wa.y * Wb.z; q:= Wa.z * Wb.y; W.x:= p - q;
p:= Wa.z * Wb.x; q:= Wa.x * Wb.z; W.y:= p - q;
p:= Wa.x * Wb.y; q:= Wa.y * Wb.x; W.z:= p - q; Result:= W
END;
FUNCTION Diff2V(Wa, Wb: Ve3D): Ve3D;
VAR W: Ve3D;
BEGIN
W.x:= Wa.x - Wb.x; W.y:= Wa.y - Wb.y;
W.z:= Wa.z - Wb.z; Result:= W
END;
FUNCTION Vunit(Pc: Reel; V: Ve3D): Ve3D;
VAR I1, N1, p, q, r, s: Reel; W: Ve3D;
BEGIN
p:= Sqr(V.x); q:= Sqr(V.y); r:= Sqr(V.z); s:= p + q;
N1:= Sqrt(r + s); IF (Pc<0) THEN I1:= 1 / N1 ELSE I1:= -1 / N1;
W.x:= V.x * I1; W.y:= V.y * I1; W.z:= V.z * I1; Result:= W
END;
FUNCTION Pscal(Wa, Wb: Ve3D): Reel;
VAR p, q, r, s: Reel;
BEGIN
p:= Wa.x * Wb.x; q:= Wa.y * Wb.y; r:= Wa.z * Wb.z;
s:= p + q; Result:= r + s
END;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Caculs relatifs au polyŠdre
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
FUNCTION CombLin3V(C1, C2, C3: Z_32; V1, V2, V3: Ve3D): Ve3D;
VAR W: Ve3D;
BEGIN
WITH W DO
BEGIN
x:= C1 * V1.x; IncR(x, C2 * V2.x); IncR(x, C3 * V3.x);
y:= C1 * V1.y; IncR(y, C2 * V2.y); IncR(y, C3 * V3.y);
z:= C1 * V1.z; IncR(z, C2 * V2.z); IncR(z, C3 * V3.z)
END;
Result:= W
END;
FUNCTION Identif_F(X1, Y1, Z1: Z_32): Byte;
// CONST Seuil = 1E-10;
VAR j, Jf: Byte; Max, p, q, r, s: Reel; W: Ve3D;
BEGIN
W:= CombLin3V(X1, Y1, Z1 + 1, Vun1, Vun2, Vun3); Jf:= 0; Max:= 0;
FOR j:= 1 TO Nface DO
BEGIN
p:= Pscal(LstF[j].Un, W); q:= p - LstF[j].Dc;
r:= Abs(q); s:= q + r;
IF (s>Max) THEN BEGIN
Jf:= j; Max:= s
END
END;
Result:= Jf
END;
FUNCTION F_Polyedre(X1, Y1, Z1: Z_32): Reel;
VAR j: Byte; p, q, r, s: Reel; W: Ve3D;
BEGIN
W:= CombLin3V(X1, Y1, Z1, Vun1, Vun2, Vun3);
s:= 0;
FOR j:= 1 TO Nface DO
BEGIN
p:= Pscal(LstF[j].Un, W); q:= p - LstF[j].Dc;
r:= Abs(q); IncR(s, q + r)
END;
Result:= s
END;
PROCEDURE Calc_Mat_Im2(La, Ha, Rc: Z_32; VAR Ma2: Tab_Pix);
CONST Seuil = 1E-10; P000: Pixel = (0, 0, 0);
VAR Iface: Byte;
Xcen, Ximg, Xm, Ycen, Yimg, Ym, Zimg, Zmin: Z_32;
u: Reel; Px: Pixel;
BEGIN
Xcen:= La DIV 2; Ycen:= Ha DIV 2; Zmin:= -2 * Rc;
FOR Xm:= 0 TO (La - 1) DO
BEGIN
Ximg:= Xm - Xcen; We(10, 40, Xm, 6);
FOR Ym:= 0 TO (Ha - 1) DO
BEGIN
Yimg:= Ym - Ycen; Zimg:= 0;
REPEAT
Dec(Zimg); u:= F_Polyedre(Ximg, Yimg, Zimg + Rcen)
UNTIL ((u<Seuil) OR (Zimg=Zmin));
IF (Zimg=Zmin) THEN Px:= P000
ELSE BEGIN
Iface:= Identif_F(Ximg, Yimg,
Zimg + Rcen);
Px:= LstC[Iface]
END;
Ma2[Xm,Ym]:= Px
END
END
END;
Voici ce que cela donne - deux fonctions ont été données pour la palette de couleur, et l'on peut à loisir y inverser les signes des termes (x, y, z):