Bonjour,
La perspective de tes schémas est bien rendue. Je tâcherai de revenir sur les équations.
Bernard-maths a écrit ... Pour la suite, je te propose un tétraèdre régulier ... tu le fais en demi-espaces, et moi en tranches d'espace.
Je propose A(3,3,3), B(3,-3,-3), C(-3,3,-3) et D(-3,-3,3) ... OK ? ...
Les coordonnées des sommets s'obtiennent à un facteur près par l'algorithme sommairement résumé:
FOR i:= -1 TO 1 DO
FOR j:= -1 TO 1 DO
FOR k:= -1 TO 1 DO
BEGIN
s:= i + j + k; p:= x * j * k;
IF (p<>0) AND ((s=-1) OR (s=3)) DO
BEGIN
x:= D * i; y:= D * j; z:= D * k
END
END;
Le tétraèdre régulier se singularisant par un dual de même nature, les normales aux faces sont opposées aux vecteurs position des sommets; elles sont par conséquent données par les conditions:
(p<>0) AND ((s=1) OR (s=-3))
Comme auparavant, les indices et les coordonnées des sommets n'ont pas été calculés.
Voici donc le tableau de résultats et l'image auxquels conduisent le programme source; les faces sont les plans tangents à la sphère centrée à l'origine et de rayon Rsph = 0.340*Rcen ; la perspective correspond aux paramètres
Latitude La = 25° , Longitude = 40° .

Figure en-dessous, pour illustration du procédé, le polyèdre à 64 faces (4
3) dont les normales sont très simplement calculées à partir de 3 entiers (i, j, k) variant de 0 à 3 (Rsph = 0.800*Rcen, La = 20°, Lo = 40°); il y a dans ce cas 3 plans de symétrie, et un centre de symétrie.
Le programme source relatif à la représentation du tétraèdre figure ci-dessous:
PROGRAM Polyedre;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Repr‚sentation d'un t‚traŠdre à partir des normales aux faces
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
USES Crt, E_Texte, U_Copie_1F, Math, U_Math;
// CONST Nsomm = 4;
CONST Nface = 4;
TYPE Ve3D = RECORD x, y, z: Reel END;
// Tab_V = ARRAY[1..Nsomm] OF Ve3D;
Face = RECORD Sa, Sb, Sc: Byte;
Un: Ve3D; Dc: Reel END;
Tab_F = ARRAY[1..Nface] OF Face;
Tab_C = ARRAY[1..Nface] OF Pixel;
VAR Rcen: Z_32; Rsph: Reel;
Vun1, Vun2, Vun3: Ve3D;
// LstS: Tab_V;
LstF: Tab_F;
LstC: Tab_C;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Utilitaires
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
FUNCTION Pvect(Wa, Wb: Ve3D): Ve3D;
VAR p, q: Reel; W: Ve3D;
BEGIN
p:= Wa.y * Wb.z; q:= Wa.z * Wb.y; W.x:= p - q;
p:= Wa.z * Wb.x; q:= Wa.x * Wb.z; W.y:= p - q;
p:= Wa.x * Wb.y; q:= Wa.y * Wb.x; W.z:= p - q; Result:= W
END;
FUNCTION Diff2V(Wa, Wb: Ve3D): Ve3D;
VAR W: Ve3D;
BEGIN
W.x:= Wa.x - Wb.x; W.y:= Wa.y - Wb.y;
W.z:= Wa.z - Wb.z; Result:= W
END;
FUNCTION Vunit(V: Ve3D): Ve3D;
VAR I1, N1, p, q, r, s: Reel; W: Ve3D;
BEGIN
p:= Sqr(V.x); q:= Sqr(V.y); r:= Sqr(V.z); s:= p + q;
N1:= Sqrt(r + s); I1:= 1 / N1;
W.x:= V.x * I1; W.y:= V.y * I1; W.z:= V.z * I1; Result:= W
END;
FUNCTION Pscal(Wa, Wb: Ve3D): Reel;
VAR p, q, r, s: Reel;
BEGIN
p:= Wa.x * Wb.x; q:= Wa.y * Wb.y; r:= Wa.z * Wb.z;
s:= p + q; Result:= r + s
END;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Caculs relatifs au polyŠdre
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
FUNCTION CombLin3V(C1, C2, C3: Z_32; V1, V2, V3: Ve3D): Ve3D;
VAR W: Ve3D;
BEGIN
WITH W DO
BEGIN
x:= C1 * V1.x; IncR(x, C2 * V2.x); IncR(x, C3 * V3.x);
y:= C1 * V1.y; IncR(y, C2 * V2.y); IncR(y, C3 * V3.y);
z:= C1 * V1.z; IncR(z, C2 * V2.z); IncR(z, C3 * V3.z)
END;
Result:= W
END;
FUNCTION Identif_F(X1, Y1, Z1: Z_32): Byte;
VAR j, Jf: Byte; Max, p, q, r, s: Reel; W: Ve3D;
BEGIN
W:= CombLin3V(X1, Y1, Z1 + 1, Vun1, Vun2, Vun3); Jf:= 0; Max:= 0;
FOR j:= 1 TO Nface DO
BEGIN
p:= Pscal(LstF[j].Un, W); q:= p - LstF[j].Dc;
r:= Abs(q); s:= q + r;
IF (s>Max) THEN BEGIN
Jf:= j; Max:= s
END
END;
Result:= Jf
END;
FUNCTION F_Polyedre(X1, Y1, Z1: Z_32): Reel;
VAR j: Byte; p, q, r, s: Reel; W: Ve3D;
BEGIN
W:= CombLin3V(X1, Y1, Z1, Vun1, Vun2, Vun3);
s:= 0;
FOR j:= 1 TO Nface DO
BEGIN
p:= Pscal(LstF[j].Un, W); q:= p - LstF[j].Dc;
r:= Abs(q); IncR(s, q + r)
END;
Result:= s
END;
PROCEDURE Calc_Mat_Im2(La, Ha, Rc: Z_32; VAR Ma2: Tab_Pix);
CONST Seuil = 1E-10; P000: Pixel = (0, 0, 0);
VAR Iface: Byte;
Xcen, Ximg, Xm, Ycen, Yimg, Ym, Zimg, Zmin: Z_32;
u: Reel; Px: Pixel;
BEGIN
Xcen:= La DIV 2; Ycen:= Ha DIV 2; Zmin:= -2 * Rc;
FOR Xm:= 0 TO (La - 1) DO
BEGIN
Ximg:= Xm - Xcen; We(10, 40, Xm, 6);
FOR Ym:= 0 TO (Ha - 1) DO
BEGIN
Yimg:= Ym - Ycen; Zimg:= 0;
REPEAT
Dec(Zimg); u:= F_Polyedre(Ximg, Yimg, Zimg + Rcen)
UNTIL ((u<Seuil) OR (Zimg=Zmin));
IF (Zimg=Zmin) THEN Px:= P000
ELSE BEGIN
Iface:= Identif_F(Ximg, Yimg,
Zimg + Rcen);
Px:= LstC[Iface]
END;
Ma2[Xm,Ym]:= Px
END
END
END;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Calcul des couleurs
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
FUNCTION Max3R(p, q, r: Reel): Reel;
VAR m: Reel;
BEGIN
IF (p>q) THEN m:= p ELSE m:= q;
IF (m<r) THEN m:= r; Result:= m
END;
CONST Kc2 = 30; Kc1 = Kc2 - 1; Kc3 = Kc2 + 1;
PROCEDURE Init_Lc(VAR L_f: Tab_F; VAR L_c: Tab_C);
CONST m = 255.499;
VAR k: Byte; s, t, u, v, w: Reel; Px: Pixel;
BEGIN
FOR k:= 1 TO Nface DO
BEGIN
WITH LstF[k].Un DO
BEGIN
u:= Frac(Kc1 * (1.4 + x)); v:= Frac(Kc2 * (1.5 + y));
w:= Frac(Kc3 * (1.6 + z)); s:= Max3R(u, v, w);
t:= m / s; Px[1]:= Round(t * u);
Px[2]:= Round(t * v); Px[3]:= Round(t * x)
END;
L_c[k]:= Px
END
END;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
D‚termination des sommets, des faces et des arˆtes
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
PROCEDURE AffF(VAR L_F: Tab_F);
CONST L1 = 2; L2 = L1 + 1; v = 11; w = 5;
VAR k: Byte;
BEGIN
E(1012); Wt(1, L1, ' j');
E(0015); Write(' Ja Jb Jc ');
E(0010); Write('Nx Ny Nz ');
E(0014); Write('Dcen');
FOR k:= 1 TO Nface DO
WITH L_f[k] DO
BEGIN
E(0012); We(1, k + L2, k, w);
E(0015); Write(Sa:w, Sb:w, Sc:w);
E(0010); Write(Un.x:v:w, Un.y:v:w, Un.z:v:w);
E(0014); Write(Dc:v:w)
END;
A_; E(1015)
END;
CONST DegRad = Pi / 180;
PROCEDURE CalcF(Rs_: Reel; VAR LstF: Tab_F);
VAR i, j, k, Sij, Sijk: Z_08; h: Byte; W_: Ve3D;
BEGIN
h:= 0;
FOR i:= -1 TO 1 DO
IF (i<>0) THEN
FOR j:= -1 TO 1 DO
IF (j<>0) THEN
BEGIN
Sij:= i + j;
FOR k:= -1 TO 1 DO
IF (k<>0) THEN
BEGIN
Sijk:= Sij + k;
IF ((Sijk=-3) OR (Sijk=1)) THEN
BEGIN
Inc(h); W_.x:= i;
W_.y:= j; W_.z:= k;
LstF[h].Un:= Vunit(W_); LstF[h].Dc:= Rs_
END
END
END
END;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Calculs relatifs au nouveau repŠre
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
PROCEDURE CalcRcRs(La, Ha: Z_32; VAR Rc_: Z_32; VAR Rs_: Reel);
BEGIN
IF (La<Ha) THEN Rc_:= La DIV 2
ELSE Rc_:= Ha DIV 2;
Rs_:= 0.340 * Rc_
END;
CONST LambdaDeg = 25.0; PhiDeg = 40.0;
PROCEDURE Calc_U0123(VAR U_1, U_2, U_3: Ve3D);
CONST DegRad = Pi / 180;
VAR Clam, Cphi, Slam, Sphi: Reel; W: Ve3D;
BEGIN
SinCos(LambdaDeg * DegRad, Slam, Clam);
SinCos(PhiDeg * DegRad, Sphi, Cphi);
W.x:= -Sphi; W.y:= Cphi; W.z:= 0; U_1:= W;
W.x:= - Slam * Cphi; W.y:= - Slam * Sphi; W.z:= Clam; U_2:= W;
W.x:= Clam * Cphi; W.y:= Clam * Sphi; W.z:= Slam; U_3:= W
END;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Programme principal
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
BEGIN
Copie_F1;
Calc_U0123(Vun1, Vun2, Vun3);
CalcRcRs(Larg_Image, Haut_Image, Rcen, Rsph);
CalcF(Rsph, LstF); AffF(LstF);
Init_Lc(LstF, LstC);
Calc_Mat_Im2(Larg_Image, Haut_Image, Rcen, Matrice_2);
Creation_F2
END.
La fonction couleur se comporte pratiquement comme un générateur pseudo-aléatoire de pixels, la plus forte composante étant systématiquement portée à 255.