Bonjour,
Voici le programme source réalisant la mise en perspective du polyèdre à 26 faces:
PROGRAM Polyedre;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Représentation en perpective des faces d'un polyèdre
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
USES Crt, E_Texte, U_Copie_1F, Math, U_Math;
CONST N_Face = 26; Nf2 = N_Face DIV 2; // Nf2 = 13
TYPE Ve3D = RECORD x, y, z: Reel END;
Fxyz = FUNCTION(h, x, y, z: Reel): Reel;
Tab_Fxyz = ARRAY[1..N_Face] OF Fxyz;
Tab_Nf = ARRAY[1..Nf2] OF Ve3D;
Tab_Px = ARRAY[1..Nf2] OF Pixel;
VAR Vun1, Vun2, Vun3: Ve3D;
LstF: Tab_Fxyz;
LstN: Tab_Nf;
LstC: Tab_Px;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Equations des faces de polyèdre
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
FUNCTION F13(h, x, y, z: Reel): Reel;
VAR p, q, r, s: Reel;
BEGIN
r:= h - z; s:= x + y; p:= Abs(r + s);
r:= h + z; q:= Abs(r - s);
r:= p + q; s:= 2 * h;
Result:= r - s
END;
FUNCTION F12(h, x, y, z: Reel): Reel;
VAR p, q, r, s: Reel;
BEGIN
r:= h - y; s:= z + x; p:= Abs(r + s);
r:= h + y; q:= Abs(r - s);
r:= p + q; s:= 2 * h;
Result:= r - s
END;
FUNCTION F11(h, x, y, z: Reel): Reel;
VAR p, q, r, s: Reel;
BEGIN
r:= h - x; s:= y + z; p:= Abs(r + s);
r:= h + x; q:= Abs(r - s);
r:= p + q; s:= 2 * h;
Result:= r - s
END;
FUNCTION F10(h, x, y, z: Reel): Reel;
VAR p, q, r, s: Reel;
BEGIN
r:= h - x; s:= y + z; p:= Abs(r - s);
r:= h + x; q:= Abs(r + s);
r:= p + q; s:= 2 * h;
Result:= r - s
END;
FUNCTION F9(h, x, y, z: Reel): Reel;
VAR p, q, r, s: Reel;
BEGIN
s:= z - x; p:= Abs(h - s); q:= Abs(h + s);
r:= p + q; s:= 2 * h; Result:= r - s
END;
FUNCTION F8(h, x, y, z: Reel): Reel;
VAR p, q, r, s: Reel;
BEGIN
s:= z + x; p:= Abs(h - s); q:= Abs(h + s);
r:= p + q; s:= 2 * h; Result:= r - s
END;
FUNCTION F7(h, x, y, z: Reel): Reel;
VAR p, q, r, s: Reel;
BEGIN
s:= y - z; p:= Abs(h - s); q:= Abs(h + s);
r:= p + q; s:= 2 * h; Result:= r - s
END;
FUNCTION F6(h, x, y, z: Reel): Reel;
VAR p, q, r, s: Reel;
BEGIN
s:= y + z; p:= Abs(h - s); q:= Abs(h + s);
r:= p + q; s:= 2 * h; Result:= r - s
END;
FUNCTION F5(h, x, y, z: Reel): Reel;
VAR p, q, r, s: Reel;
BEGIN
s:= x - y; p:= Abs(h - s); q:= Abs(h + s);
r:= p + q; s:= 2 * h; Result:= r - s
END;
FUNCTION F4(h, x, y, z: Reel): Reel;
VAR p, q, r, s: Reel;
BEGIN
s:= x + y; p:= Abs(h - s); q:= Abs(h + s);
r:= p + q; s:= 2 * h; Result:= r - s
END;
FUNCTION F3(h, x, y, z: Reel): Reel;
VAR p, q, r, s: Reel;
BEGIN
p:= Abs(h - z); q:= Abs(h + z);
r:= p + q; s:= 2 * h;
Result:= r - s
END;
FUNCTION F2(h, x, y, z: Reel): Reel;
VAR p, q, r, s: Reel;
BEGIN
p:= Abs(h - y); q:= Abs(h + y);
r:= p + q; s:= 2 * h;
Result:= r - s
END;
FUNCTION F1(h, x, y, z: Reel): Reel;
VAR p, q, r, s: Reel;
BEGIN
p:= Abs(h - x); q:= Abs(h + x);
r:= p + q; s:= 2 * h;
Result:= r - s
END;
PROCEDURE InitF(VAR L_F: Tab_Fxyz);
BEGIN
L_F[ 1]:= F1; L_F[ 2]:= F2; L_F[ 3]:= F3;
L_F[ 4]:= F4; L_F[ 5]:= F5; L_F[ 6]:= F6;
L_F[ 7]:= F7; L_F[ 8]:= F8; L_F[ 9]:= F9;
L_F[10]:= F10; L_F[11]:= F11; L_F[12]:= F12; L_F[13]:= F13;
END;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Initialisation des fonctions
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
FUNCTION CombLin3V(C1, C2, C3: Z_32; V1, V2, V3: Ve3D): Ve3D;
VAR W: Ve3D;
BEGIN
WITH W DO
BEGIN
x:= C1 * V1.x; IncR(x, C2 * V2.x); IncR(x, C3 * V3.x);
y:= C1 * V1.y; IncR(y, C2 * V2.y); IncR(y, C3 * V3.y);
z:= C1 * V1.z; IncR(z, C2 * V2.z); IncR(z, C3 * V3.z)
END;
Result:= W
END;
FUNCTION F_Face(A1, B1, X1, Y1, Z1: Z_32): Byte;
CONST Seuil = 1E-10;
VAR j, Jf: Byte; A2, A3: Z_32; r: Reel; W: Ve3D;
BEGIN
W:= CombLin3V(X1, Y1, Z1 + 1, Vun1, Vun2, Vun3);
Jf:= 0; A2:= A1 + B1; A3:= A2 + B1;
FOR j:= 1 TO 3 DO BEGIN
r:= LstF[j](A1, W.x, W.y, W.z);
IF (r>Seuil) THEN Jf:= j
END;
FOR j:= 4 TO 9 DO BEGIN
r:= LstF[j](A2, W.x, W.y, W.z);
IF (r>Seuil) THEN Jf:= j
END;
FOR j:= 10 TO Nf2 DO BEGIN
r:= LstF[j](A3, W.x, W.y, W.z);
IF (r>Seuil) THEN Jf:= j
END;
Result:= Jf
END;
FUNCTION F_Polyedre(A1, B1, X1, Y1, Z1: Z_32): Reel;
VAR j: Byte; A2, A3: Z_32; s: Reel; W: Ve3D;
BEGIN
W:= CombLin3V(X1, Y1, Z1, Vun1, Vun2, Vun3);
s:= 0; A2:= A1 + B1; A3:= A2 + B1;
FOR j:= 1 TO 3 DO IncR(s, LstF[j](A1, W.x, W.y, W.z));
FOR j:= 4 TO 9 DO IncR(s, LstF[j](A2, W.x, W.y, W.z));
FOR j:= 10 TO Nf2 DO IncR(s, LstF[j](A3, W.x, W.y, W.z));
Result:= s
END;
PROCEDURE Calc_Mat_Im2(La, Ha: Z_32; VAR Ma2: Tab_Pix);
CONST Seuil = 1E-10; P000: Pixel = (0, 0, 0);
VAR Icoul: Byte;
Apol,Bpol, Rcen, Xcen, Ximg, Xm, Ycen, Yimg, Ym, Zimg, Zmin: Z_32;
u: Reel; Px: Pixel;
BEGIN
Xcen:= La DIV 2; Ycen:= Ha DIV 2;
IF (La<Ha) THEN Rcen:= Xcen
ELSE Rcen:= Ycen;
Zmin:= -2 * Rcen;
Apol:= Round(0.8628 * Rcen); Bpol:= Round(0.3574 * Rcen);
FOR Xm:= 0 TO (La - 1) DO
BEGIN
Ximg:= Xm - Xcen;
FOR Ym:= 0 TO (Ha - 1) DO
BEGIN
Yimg:= Ym - Ycen; Zimg:= 0; We(10, 40, Xm, 6);
REPEAT
Dec(Zimg);
u:= F_Polyedre(Apol, Bpol, Ximg, Yimg, Zimg + Rcen)
UNTIL ((u<Seuil) OR (Zimg=Zmin));
IF (Zimg=Zmin) THEN Px:= P000
ELSE BEGIN
Icoul:= F_Face(Apol, Bpol, Ximg, Yimg,
Zimg + Rcen);
Px:= LstC[Icoul]
END;
Ma2[Xm,Ym]:= Px
END
END
END;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Détermination de la couleur des faces en fonction de leur orientation
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
FUNCTION Pscal(W1, W2: Ve3D): Reel;
VAR p: Reel;
BEGIN
p:= W1.x * W2.x; IncR(p, W1.y * W2.y);
IncR(p, W1.z * W2.z); Result:= p
END;
PROCEDURE InitC(VAR L_C: Tab_Px);
CONST M1 = 240; M2 = 255.449;
VAR j, k: Byte; m, p, q, r, s, u, v, w: Reel; Px: Pixel;
BEGIN
FOR j:= 1 TO Nf2 DO
BEGIN
p:= Pscal(LstN[j], Vun1); u:= 1 + p;
q:= Pscal(LstN[j], Vun2); v:= 1 + q;
r:= Pscal(LstN[j], Vun3); w:= 1 + r;
IF (u>v) THEN m:= u ELSE m:= v; IF (m<w) THEN m:= w;
IF (p<0) OR ((q<0) OR (r<0)) THEN s:= M1 / m
ELSE s:= M2 / m;
Px[1]:= Round(u * s); Px[2]:= Round(v * s);
Px[3]:= Round(w * s); L_C[j]:= Px
END
END;
PROCEDURE InitN(VAR L_N: Tab_Nf);
CONST g = 0.707106781187; // g = Rac(1/2)
h = 0.577350269190; // h = Rac(1/3)
Nf: Tab_Nf = ((x:1; y:0; z:0),
(x:0; y:1; z:0),
(x:0; y:0; z:1),
(x: g; y: g; z: 0), (x:-g; y: g; z: 0),
(x: 0; y: g; z: g), (x: 0; y:-g; z: g),
(x: g; y: 0; z: g), (x: g; y: 0; z:-g),
(x: h; y: h; z: h), (x:-h; y: h; z: h),
(x: h; y:-h; z: h), (x: h; y: h; z:-h));
BEGIN
L_N:= Nf
END;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Orientation spatiale du nouveau repère
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
CONST LambdaDeg = 10.0; PhiDeg = 25.0;
PROCEDURE Calc_U123(VAR U_1, U_2, U_3: Ve3D);
CONST DegRad = Pi / 180;
VAR Clam, Cphi, Slam, Sphi: Reel; W: Ve3D;
BEGIN
SinCos(LambdaDeg * DegRad, Slam, Clam);
SinCos(PhiDeg * DegRad, Sphi, Cphi);
W.x:= -Sphi; W.y:= Cphi; W.z:= 0; U_1:= W;
W.x:= - Slam * Cphi; W.y:= - Slam * Sphi; W.z:= Clam; U_2:= W;
W.x:= Clam * Cphi; W.y:= Clam * Sphi; W.z:= Slam; U_3:= W
END;
(*HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH
Programme principal
HHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHHH*)
BEGIN
Copie_F1;
Calc_U123(Vun1, Vun2, Vun3);
InitF(LstF);
InitN(LstN);
InitC(LstC);
Calc_Mat_Im2(Larg_Image, Haut_Image, Matrice_2);
Creation_F2
END.
J'ai perdu beaucoup de temps dans la recherche de la meilleure (?) fonction retournant la couleur des faces en fonction de l'orientation de leur norme; il faut préserver les contrastes ainsi qu'un minimum de luminosité, mais c'est à la limite affaire de choix personnel.
Voici ce que l'on obtient pour diverses valeurs de la constante (
M1) présente dans la procédure
InitC(...):
M1 = 130, 160, 180, 200, 220, 240
