Bernard-maths a écrit ... Il FAUT rester DANS le polygone ...
Si l'on veut voir les frontières, il faut quand même bien les franchir ...
Bernard-maths a écrit ... Je viens de mettre sur GeoGebra une figure, "A_faire_éclater" .
C'est une belle bête ...
Et où peut-on admirer l'animal ?
Bernard-maths a écrit ... mais je ne suis pas d'accord sur la galère ! ...
Je me suis borné à reprendre tes suggestions par voie analytique, et les développements ne présentent pas de difficulté insurmontable !
Voici ce que donne la transposition algorithmique de l'égalité Σ
i=1N(F(M, i, j)) = Σ
i=1N|F(M, i, j)| .
Elle conduit à un résultat conforme aux prévisions dans le cas de tout polygone convexe:
Elle ne fonctionne plus dans le cas d'un polygone concave ou croisé:
Voici le cœur du programme source
PROGRAM Polygone;
USES Crt, E_Texte, U_Copie_1F, Math;
CONST Nsomm = 7;
TYPE Tab_E = ARRAY[1..Nsomm] OF Reel;
Ve_2D = RECORD x, y: Z_32 END;
Tab_V = ARRAY[1..Nsomm] OF Ve_2D;
CONST LstX: Tab_E = (0.070, 0.500, 0.800, 0.950, 0.900, 0.350, 0.100);
LstY: Tab_E = (0.070, 0.100, 0.200, 0.800, 0.950, 0.850, 0.550);
VAR Polygone: Tab_V;
PROCEDURE Segment(X1, Y1, X2, Y2: Z_32; VAR Ma2: Tab_Pix);
CONST CoulA: Pixel = (0, 255, 0);
VAR Dx, Dy, k, Np, Xm, Ym: Z_32; Kx, Ky: Reel;
BEGIN
Dx:= X2 - X1; Dy:= Y2 - Y1;
Np:= 1; Inc(Np, Abs(Dx)); Inc(Np, Abs(Dy));
Kx:= Dx / Np; Ky:= Dy / Np;
FOR k:= 0 TO Np DO
BEGIN
Xm:= X1; Inc(Xm, Round(k * Kx));
Ym:= Y1; Inc(Ym, Round(k * Ky));
Ma2[Xm, Ym]:= CoulA
END
END;
PROCEDURE Trace_A;
VAR i, j: Byte;
BEGIN
FOR i:= 1 TO Nsomm DO
BEGIN
j:= i MOD Nsomm; Inc(j);
Segment(Polygone[i].x, Polygone[i].y,
Polygone[j].x, Polygone[j].y, Matrice_2)
END
END;
PROCEDURE Croix(L_1, H_1, Xc, Yc, Lc: Z_32; VAR Ma2: Tab_Pix);
CONST CoulS: Pixel = (255, 0, 0);
VAR x, Xmax, Xmin, y, Ymax, Ymin: Z_32;
BEGIN
Xmin:= Xc - Lc; IF (Xmin<0) THEN Xmin:= 0;
Xmax:= Xc + Lc; IF (Xmax>L_1) THEN Xmax:= L_1;
Ymin:= Yc - Lc; IF (Ymin<0) THEN Ymin:= 0;
Ymax:= Yc + Lc; IF (Ymax>H_1) THEN Ymax:= H_1;
FOR x:= Xmin TO Xmax DO Ma2[x, Yc]:= CoulS;
FOR y:= Ymin TO Ymax DO Ma2[Xc, y]:= CoulS
END;
PROCEDURE Trace_S(La, Ha: Z_32);
VAR k: Byte; Ha1, La1: Z_32;
BEGIN
La1:= La - 1; Ha1:= Ha - 1;
FOR k:= 1 TO Nsomm DO
Croix(La1, Ha1, Polygone[k].x, Polygone[k].y, 20, Matrice_2)
END;
FUNCTION Aire(Xp, Yp: Z_32; V1, V2: Ve_2D): Z_32;
VAR Dx1, Dx2, Dy1, Dy2, p, q: Z_32;
BEGIN
Dx1:= V1.x - Xp; Dy1:= V1.y - Yp;
Dx2:= V2.x - Xp; Dy2:= V2.y - Yp;
p:= Dx1 * Dy2; q:= Dx2 * Dy1; Result:= p - q
END;
PROCEDURE Calc_Mat_Im2(La, Ha: Z_32; VAR Ma2: Tab_Pix);
CONST Delta = 0;
Pzero: Pixel = ( 0, 0, 0);
Cfond: Pixel = (105, 0, 255);
VAR i, j: Byte; Ds, S, Sc, Xc, Xm, Yc, Ym: Z_32; Px: Pixel;
BEGIN
Xc:= La DIV 2; Yc:= Ha DIV 2; Sc:= 0;
FOR i:= 1 TO Nsomm DO
BEGIN
j:= i MOD Nsomm; Inc(j);
Ds:= Aire(Xc, Yc, Polygone[i], Polygone[j]);
Inc(Sc, Ds)
END;
FOR Xm:= 0 TO (La - 1) DO
FOR Ym:= 0 TO (Ha - 1) DO
BEGIN
S:= 0;
FOR i:= 1 TO Nsomm DO
BEGIN
j:= i MOD Nsomm; Inc(j);
Ds:= Aire(Xm, Ym, Polygone[i], Polygone[j]);
Inc(S, Abs(Ds))
END;
IF (Sc=S) THEN Px:= Cfond ELSE Px:= Pzero;
Ma2[Xm,Ym]:= Px
END
END;
PROCEDURE Init_Pol(VAR Pol_: Tab_V);
VAR k: Byte;
BEGIN
FOR k:= 1 TO Nsomm DO
WITH Pol_[k] DO BEGIN
x:= Round(LstX[k] * Larg_Image);
y:= Round(LstY[k] * Haut_Image)
END
END;
BEGIN
Copie_F1; // Copie d'un fichier initial
Init_Pol(Polygone); // Initialisation du polygone
Calc_Mat_Im2(Larg_Image, Haut_Image, Matrice_2); // Calcul de la matrice de pixels du corps de la seconde image
Trace_A; // Tracé des arêtes
Trace_S(Larg_Image, Haut_Image); // Pointage des sommets
Creation_F2 // Création du fichier de la seconde image
END.